Main Page

From LiLaMorph
Jump to navigation Jump to search

Welcome to LiLaMorph Wikibase. This instance has been created in September 2025.

We are using this instance for building a Latin verb forms LOD dataset, with the final goal of enriching Wikidata Latin lexemes, and for corpus annotation experiments (matching tokens in morphologically annotated corpora to Wikibase forms).

A comprehensive description will appear in a forthcoming paper. Scripts for production of the datasets, copies of the source data, and mapping files used in these experiments are available here. On November 7, 2025, a copy of the main files was deposited with DOI 10.5281/zenodo.17553591.

See details about this Wikibase at Wikibase World Q2840.

Datasets on this Wikibase

This query lists the datasets on this Wikibase, their data sources, and their number of entries. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>

select ?collection ?collectionLabel ?data_source (count(distinct ?entry) as ?entries)
where {
  ?collection lmdp:P5 lmwb:Q8; lmdp:P23 ?data_source.
  ?entry lmdp:P14 ?collection.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "la, en". }
} group by ?collection ?collectionLabel ?data_source ?entries

Try it!

PrinParLat flexemes collection (lexicon version 1)

In a first experiment, we created a wikibase lexical entry for every PrinParLat flexeme. See the list of entries with number of associated forms using this query. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>

select distinct ?lila_lemma_id ?flexeme_canonical_form ?flexeme_num ?flexeme (count (?form) as ?forms)
where {
  ?flexeme lmdp:P14 lmwb:Q9; lmdp:P1 ?lila_lemma_id; wikibase:lemma ?flexeme_canonical_form.
  ?flexeme ontolex:lexicalForm ?form.
  bind(xsd:integer(strafter(str(?flexeme), concat(str(lmwb:),"L"))) as ?flexeme_num)

} group by ?lila_lemma_id ?flexeme_canonical_form ?flexeme_num ?flexeme ?forms order by ?flexeme_canonical_form

Try it!

PrinParLat lexemes collection (lexicon version 2)

In a second experiment, we created a wikibase lexical entry for every PrinParLat lexeme. That is, PrinParLat flexemes associated to the same PrinParLat lexeme are conflated in the same lexical entry; inside the entry, forms with identical morph cell description and identical orthographical form and identical analyzed form are merged to each other. See the entries with number of forms using this query. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>

select distinct ?prinparlat_lexeme ?lila_lemma_id ?lemma ?lexeme_num ?lexeme (count (?form) as ?forms)
where {
  ?lexeme lmdp:P14 lmwb:Q14; lmdp:P8 ?prinparlat_lexeme; lmdp:P1 ?lila_lemma_id; wikibase:lemma ?lemma.
  ?lexeme ontolex:lexicalForm ?form.
  bind(xsd:integer(strafter(str(?lexeme), concat(str(lmwb:),"L"))) as ?lexeme_num)

} group by ?prinparlat_lexeme ?lila_lemma_id  ?lemma ?lexeme_num ?lexeme ?forms order by ?lemma

Try it!

The following query shows the form conflations: 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>

 select 
  ?lila_lemma_id ?lemma ?lexeme ?form ?form_rep (count(?flexeme) as ?count) (group_concat(?flexeme) as ?flexemes)                   
     where {    
  ?lexeme lmdp:P14 lmwb:Q14; lmdp:P1 ?lila_lemma_id; wikibase:lemma ?lemma.
  ?lexeme ontolex:lexicalForm ?form.
  ?form lmdp:P6 ?flexeme; ontolex:representation ?form_rep.
  } group by ?lila_lemma_id ?lemma ?lexeme ?form ?form_rep ?count ?flexemes order by desc(?count)

Try it!

PrinParLat lexemes collection (lexicon version 3)

In a third experiment, after detecting several issues in the lexemes collection (lexicon version 2) - in the source data, and in the conflation and upload process -, we also created a wikibase lexical entry for every PrinParLat lexeme. That is, PrinParLat flexemes associated to the same PrinParLat lexeme are conflated in the same lexical entry; inside the entry, forms with identical morph cell description and identical orthographical form and identical analyzed form are merged to each other. See the entries with number of forms using this query. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>

select distinct ?prinparlat_lexeme ?lila_lemma_id ?lemma ?lexeme_num ?lexeme (count (?form) as ?forms)
where {
  ?lexeme lmdp:P14 lmwb:Q15; lmdp:P8 ?prinparlat_lexeme; lmdp:P1 ?lila_lemma_id; wikibase:lemma ?lemma.
  ?lexeme ontolex:lexicalForm ?form.
  bind(xsd:integer(strafter(str(?lexeme), concat(str(lmwb:),"L"))) as ?lexeme_num)

} group by ?prinparlat_lexeme ?lila_lemma_id  ?lemma ?lexeme_num ?lexeme ?forms order by ?lemma

Try it!

The following query shows the form conflations: 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>

 select 
  ?lila_lemma_id ?lemma ?lexeme ?form ?form_rep (count(?flexeme) as ?count) (group_concat(?flexeme) as ?flexemes)                   
     where {    
  ?lexeme lmdp:P14 lmwb:Q15; lmdp:P1 ?lila_lemma_id; wikibase:lemma ?lemma.
  ?lexeme ontolex:lexicalForm ?form.
  ?form lmdp:P6 ?flexeme; ontolex:representation ?form_rep.
  } group by ?lila_lemma_id ?lemma ?lexeme ?form ?form_rep ?count ?flexemes order by desc(?count)

Try it!


Index Thomisticus Treebank token collection

In an additional experiment, we created a wikibase item for every IT-TB token. We got the token information from LiLa using this query. Access the token items by searching for token labels (source text literals) in the ElasticSearch index search on top of this page or here sorted by last-edited, or using this query. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>

select distinct ?token (iri(concat("http://lila-erc.eu/data/corpora/ITTB/id/token/",?token_id)) as ?token_link) ?token_label ?linked_lila_lemma 
 (group_concat(distinct strafter(str(?linked_lexeme), str(lmwb:))) as ?linked_lexemes)
 (group_concat(distinct str(?linked_lex_lem)) as ?linked_lexeme_lemmas) 
 (group_concat(distinct ?udp_label) as ?udp_feat)
where {
  ?token lmdp:P14 lmwb:Q13; 
         lmdp:P16 ?linked_lila_lemma; 
         lmdp:P17 ?token_id; 
         lmdp:P18 [lmdp:P7 ?udp_label]; 
         rdfs:label ?token_label. filter(lang(?token_label)="la")
  optional {?linked_lexeme lmdp:P14 lmwb:Q10; lmdp:P1 ?linked_lila_lemma; 
                           wikibase:lemma ?linked_lex_lem.}
  
} group by ?token ?token_id ?token_label ?linked_lila_lemma ?lexemes ?linked_lexeme_lemmas ?udp_feat

Try it!

Tokens linked to more than one LiLa lemma

This query lists tokens linked ambiguously to LiLa lemmata in the ITTB source on LiLa. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

select distinct ?token (iri(concat("http://lila-erc.eu/data/corpora/ITTB/id/token/",?token_id)) as ?token_link) ?tokenLabel (group_concat(distinct ?udp_label) as ?udp_feat) ?linked_lila_lemma ?infclassLabel
 
where {
  { select ?token (count(?linked_lila_st) as ?count) where {
    ?token lmdp:P14 lmwb:Q13; lmp:P16 ?linked_lila_st.
      } group by ?token ?count 
  }
  filter(?count > 1)
  ?token lmp:P16 [lmps:P16 ?linked_lila_lemma; lmpq:P22 ?infclass];
         lmdp:P17 ?token_id; 
         lmdp:P18 [lmdp:P7 ?udp_label].
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "la,en". }  
} group by ?token ?token_id ?tokenLabel ?udp_feat ?linked_lila_lemma ?infclassLabel
# order by ?token_link # order usually leads to timeout; download CSV and order by token

Try it!


Feature statistics

As an example, the distribution of Tense features in ITTB tokens. 

#defaultView:BubbleChart
PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>

select ?feat (count(distinct ?token) as ?tokens)

where {
  ?token lmdp:P18 [lmdp:P7 ?feat].
 filter(regex(?feat,"Tense#"))
  
} group by ?feat ?tokens
order by desc(?tokens)

Try it!


Linking ITTB tokens to PrinParLat forms

A linking algorithm matches ITTB tokens to forms in the PrinParLat lexemes collection (lexicon version 3).

Linked vs. unlinked tokens: numbers

This query shows amounts of linked and unlinked tokens in ITTB verb token collection. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

SELECT ?token_collection ?token_collectionLabel ?lexiconLabel (COUNT(distinct ?linked_token) AS ?linked_tokens) (COUNT(?unlinked_token) AS ?unlinked_tokens) WHERE {
  values ?token_collection {lmwb:Q13} values ?lexicon {lmwb:Q15}
  {?linked_token lmdp:P14 ?token_collection;
    lmp:P21 [lmpq:P14 ?lexicon].} union
  {?unlinked_token lmdp:P14 ?token_collection.
  FILTER(NOT EXISTS { ?unlinked_token lmp:P21 [lmpq:P14 ?lexicon]. })}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "la, en". }
}
GROUP BY ?token_collection ?token_collectionLabel ?lexiconLabel ?linked_tokens ?unlinked_tokens

Try it!


Linked tokens

This query shows token-to-form links. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

select distinct ?token (iri(concat("http://lila-erc.eu/data/corpora/ITTB/id/token/",?token_id)) as ?token_link) ?token_label 
 ?lexiconLabel ?linked_form ?linked_form_rep ?linked_formcell 

where { values ?lexicon {lmwb:Q15} # Prinparlat lexemes collection version 3
  ?token lmdp:P14 lmwb:Q13; # in collection ITTB
         lmdp:P17 ?token_id; 
         lmp:P21 [lmps:P21 ?linked_form; lmpq:P14 ?lexicon];
         rdfs:label ?token_label. filter(lang(?token_label)="la")
  ?linked_form lmdp:P24 [lmdp:P10 ?linked_formcell]; ontolex:representation ?linked_form_rep.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "la, en". }
} group by ?token ?token_id ?token_label ?lexiconLabel ?linked_form ?linked_form_rep ?linked_formcell

Try it!

This query shows those tokens that have been linked to a PrinParLat form of the PrinParLat lexemes collection, together with the linking at lexeme level that stems from the lila:hasLemma triple on the token in LiLa (Wikibase lexemes linked to that LiLa lemma are listed). 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

select distinct ?token (iri(concat("http://lila-erc.eu/data/corpora/ITTB/id/token/",?token_id)) as ?token_link) ?token_label 
 ?linked_form ?linked_form_rep ?linked_formcell 
 (group_concat(distinct ?udp_label) as ?token_udp_feat)
 (group_concat(distinct ?tokenlinked_lila_lem) as ?tokenlinked_lila_lemmas)
 (group_concat(distinct strafter(str( ?tokenlinked_lexeme), str(lmwb:))) as  ?tokenlinked_lexemes)
 (group_concat(distinct str(?tokenlinked_lex_lem)) as ?tokenlinked_lexeme_lemmas) 

where { values ?lexicon {lmwb:Q15} # Prinparlat lexemes collection version 3
  ?token lmdp:P14 lmwb:Q13; # in collection ITTB
         lmdp:P16 ?tokenlinked_lila_lem; 
         lmdp:P17 ?token_id; 
         lmdp:P18 [lmdp:P7 ?udp_label]; 
         lmp:P21 [lmps:P21 ?linked_form; lmpq:P14 ?lexicon];
         rdfs:label ?token_label. filter(lang(?token_label)="la")
  ?linked_form lmdp:P24 [lmdp:P10 ?linked_formcell]; ontolex:representation ?linked_form_rep.
  optional {?tokenlinked_lexeme lmdp:P14 lmwb:Q15; lmdp:P1 ?tokenlinked_lila_lem; 
                           wikibase:lemma  ?tokenlinked_lex_lem.}
  
} group by ?token ?token_id ?token_label ?linked_form ?linked_form_rep ?linked_formcell ?token_udp_feat  ?tokenlinked_lila_lemmas ?tokenlinked_lexemes ?tokenlinked_lexeme_lemmas

Try it!

Unambiguously linked tokens

This query lists Q13 collection tokens that are linked to one Q15 collection form. 

#title:Unambiguously linked tokens
PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

select distinct ?token (iri(concat("http://lila-erc.eu/data/corpora/ITTB/id/token/",?token_id)) as ?token_link) ?token_label ?linked_form ?form_rep ?analysed_form ?cell (group_concat(?flex_id;SEPARATOR=", ") as ?flex_ids)

where { values ?lexicon {lmwb:Q15} # Prinparlat lexemes collection version 3
  ?token lmdp:P14 lmwb:Q13; lmdp:P17 ?token_id; rdfs:label ?token_label. # in collection ITTB
       filter(lang(?token_label)="la")
    { select ?token (count(?linked_form_for_count) as ?linked_forms_count) where
     { ?token lmp:P21 [lmps:P21 ?linked_form_for_count; lmpq:P14 ?lexicon].
       } group by ?token ?linked_forms_count 
     }
   filter(?linked_forms_count = 1)
    ?token lmp:P21 [lmps:P21 ?linked_form; lmpq:P14 ?lexicon].
       ?linked_form ontolex:representation ?form_rep; lmdp:P12 ?analysed_form; lmdp:P24 [lmdp:P10 ?cell]; lmdp:P6 ?flex_id.
 
} group by ?token ?token_id ?token_label ?linked_form ?form_rep ?analysed_form ?cell ?flex_ids

Try it!

Ambiguously linked tokens

Form counts

This query lists tokens, amounts of linked forms, and linked form ids. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

select distinct ?token ?tokenLabel ?linked_forms ?linked_forms_ids

where { values ?lexicon {lmwb:Q15} # Prinparlat lexemes collection version 3
  ?token lmdp:P14 lmwb:Q13. # in collection ITTB
     { select ?token (count(?linked_form) as ?linked_forms) (group_concat(distinct ?form_id; SEPARATOR=", ") as ?linked_forms_ids) where   
        { 
       ?token lmp:P21 [lmps:P21 ?linked_form; lmpq:P14 ?lexicon].
       bind(strafter(str(?linked_form),str(lmwb:)) as ?form_id)
        } group by ?token ?linked_forms ?linked_forms_ids
     }
   filter(?linked_forms > 1)
   SERVICE wikibase:label { bd:serviceParam wikibase:language "la". } 
}  order by desc(?linked_forms)

Try it!


List of ambiguous links

This query lists tokens and linked forms, for those tokens that are linked to more than one form. 

#title:Ambiguously linked tokens
PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

select distinct ?token ?token_label ?linked_form ?form_rep ?analysed_form ?cell (group_concat(?flex_id;SEPARATOR=", ") as ?flex_ids)

where { values ?lexicon {lmwb:Q15} # Prinparlat lexemes collection version 3
  ?token lmdp:P14 lmwb:Q13; rdfs:label ?token_label. # in collection ITTB
       filter(lang(?token_label)="la")
    { select distinct ?token (count(?linked_form_for_count) as ?linked_forms) where
     { ?token lmp:P21 [lmps:P21 ?linked_form_for_count; lmpq:P14 ?lexicon].
       } group by ?token ?linked_forms 
     }
   filter(?linked_forms > 1)
    ?token lmp:P21 [lmps:P21 ?linked_form; lmpq:P14 ?lexicon].
       ?linked_form ontolex:representation ?form_rep; lmdp:P12 ?analysed_form; lmdp:P24 [lmdp:P10 ?cell]; lmdp:P6 ?flex_id.
 
} group by ?token ?token_label ?linked_form ?form_rep ?analysed_form ?cell ?flex_ids
order by ?token

Try it!


Linked forms frequency ranking

This query shows linked forms, ordered by count of linked tokens. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

select ?form ?form_rep ?formcell ?lexeme ?lemma (count(distinct ?token) as ?tokens)

where { values ?lexicon {lmwb:Q15} # Prinparlat lexemes collection version 3
  ?lexeme lmdp:P14 ?lexicon; ontolex:lexicalForm ?form; wikibase:lemma ?lemma.
  ?token lmdp:P14 lmwb:Q13; lmdp:P21 ?form.
  ?form lmdp:P24 [lmdp:P10 ?formcell]; ontolex:representation ?form_rep.
  
} group by ?form ?form_rep ?formcell ?lexeme ?lemma ?tokens
order by desc(?tokens)

Try it!


Linked PrinParLat lexemes frequency ranking

This query shows lexemes forms of which are linked from tokens, ordered by count of linked tokens. 

PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

select ?prinparlat_lexeme (sample(?lemma) as ?lexeme_lemma) (count(distinct ?token) as ?tokens)

where { values ?lexicon {lmwb:Q15} # Prinparlat lexemes collection version 3
  ?lexical_entry lmdp:P14 ?lexicon; lmdp:P8 ?prl_lexeme; ontolex:lexicalForm ?form; wikibase:lemma ?lemma.
  ?token lmdp:P14 lmwb:Q13; lmdp:P21 ?form.
  bind(iri(concat("http://lila-erc.eu/data/lexicalResources/prinparlat/id/lexeme_",?prl_lexeme)) as ?prinparlat_lexeme)
  
} group by ?prinparlat_lexeme ?lexeme_lemma ?tokens
order by desc(?tokens)

Try it!


Paralex cell frequency ranking

This query shows the frequency of linked forms morphological description ("cells"), ordered by count of linked tokens. 

#defaultView:BubbleChart
PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

select ?linked_formcell ?formcell_label (count(distinct ?token) as ?tokens)

where { values ?lexicon {lmwb:Q15} # Prinparlat lexemes collection version 3
  ?token lmp:P21 [lmps:P21 ?linked_form; lmpq:P14 ?lexicon].
  ?lexeme ontolex:lexicalForm ?linked_form; wikibase:lemma ?lemma.
  ?linked_form lmdp:P24 ?linked_formcell; ontolex:representation ?linked_form_rep.
  ?linked_formcell lmdp:P10 ?formcell_label.
  
} group by ?linked_formcell ?formcell_label ?tokens
order by desc(?tokens)

Try it!


Unlinked tokens

This query shows tokens that are not yet linked to any PrinParLat form, although the lexeme linked through the hasLemma annotation on the token in LiLa is present on this Wikibase. 

#title: Tokens that are still not linked, although the lila lemma linked from them is present on this Wikibase
PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX lmp: <https://lilamorph.wikibase.cloud/prop/>
PREFIX lmps: <https://lilamorph.wikibase.cloud/prop/statement/>
PREFIX lmpq: <https://lilamorph.wikibase.cloud/prop/qualifier/>

select ?token (iri(concat("http://lila-erc.eu/data/corpora/ITTB/id/token/",?token_id)) as ?token_link) ?token_label 
 (group_concat(?udp_label) as ?token_udp_feat)
 ?tokenlinked_lila_lemma
 ?tokenlinked_lexeme
 ?tokenlinked_lex_lemma

where {
  ?token lmdp:P14 lmwb:Q13; # in collection ITTB
         lmdp:P16 ?tokenlinked_lila_lemma; 
         lmdp:P17 ?token_id; 
         lmdp:P18 [lmdp:P7 ?udp_label]; 
         rdfs:label ?token_label. filter(lang(?token_label)="la")
  filter not exists {?token lmp:P21 [].} # Prinparlat lexemes collection version 3
  ?tokenlinked_lexeme lmdp:P14 lmwb:Q15; lmdp:P1 ?tokenlinked_lila_lemma; 
                           wikibase:lemma  ?tokenlinked_lex_lemma.
  
} group by ?token ?token_id ?token_label ?token_udp_feat  ?tokenlinked_lila_lemma ?tokenlinked_lexeme ?tokenlinked_lex_lemma
order by ?token_label

Try it!


PrinParLat lexemes: missing verbs

This query lists Lila verbs linked from tokens which are not present in Q14 collection. 

#title: Tokens that are linked to a lila verb which is not present in collection Q15
PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>

select distinct ?lila_lemma (iri(concat("http://lila-erc.eu/data/id/",?lila_lemma)) as ?lila_link) 


where {
  ?token lmdp:P14 lmwb:Q13; # in collection ITTB
         lmdp:P16 ?lila_lemma.
  filter not exists {
  ?tokenlinked_lexeme lmdp:P14 lmwb:Q15; lmdp:P1 ?lila_lemma.
                    }
} group by ?lila_lemma order by ?lila_lemma

Try it!

This query brings information about the missing verbs from LiLa. 

#title: lila verbs not present in collection Q15, with information from LiLa sparql endpoint
PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix lila: <http://lila-erc.eu/ontologies/lila/>

select distinct ?lila_lemma ?lila_uri ?lemma ?type ?type_label

where {
  ?token lmdp:P14 lmwb:Q13; # in collection ITTB
         lmdp:P16 ?lila_lemma.
  filter not exists {
  ?lexeme lmdp:P14 lmwb:Q15; lmdp:P1 ?lila_lemma.
                    }
  bind (iri(concat("http://lila-erc.eu/data/id/",?lila_lemma)) as ?lila_uri)
  
  SERVICE <https://lila-erc.eu/sparql/lila_knowledge_base/sparql> { 
    select ?lila_uri ?lemma ?type ?type_label where {
      ?lila_uri rdfs:label ?lemma; lila:hasInflectionType ?type. 
      ?type rdfs:label ?type_label.
     } 
  } 
  
} group by ?lila_lemma ?lila_uri ?lemma ?type ?type_label order by ?lila_lemma

Try it!


Controlled vocabularies mappings

PrinParLat morphological cell descriptors (Leipzig abbreviations)

This query shows mappings of Leipzig morphological feature abbreviations to UDP and Wikidata, and, through Wikidata, to LexInfo features. 

#title: PrinParLat Leipzig features and UDP and Wikidata maps, and, via Wikidata, lexinfo 3.0
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>

select distinct ?feat ?feat_label ?leipzig (group_concat(distinct ?udp_label; SEPARATOR="+") as ?udp_maps) ?wikidata ?wikidata_enlabel ?wikidata_lalabel ?wikidata_desc ?lexinfo_match 
       
where { 
  ?feat lmdp:P5 lmwb:Q7; lmdp:P10 ?leipzig; lmdp:P2 ?wd; lmdp:P9 ?udp_map; rdfs:label ?feat_label. filter (lang(?feat_label)="en")
  ?udp_map rdfs:label ?udp_label. filter (lang(?udp_label)="en")
  bind(iri(concat(str(wd:),?wd)) as ?wikidata)
  SERVICE <https://query.wikidata.org/sparql> {
           select distinct ?wikidata ?wikidata_enlabel ?wikidata_lalabel ?wikidata_desc ?lexinfo_match where 
              {?wikidata rdfs:label ?wikidata_enlabel. filter (lang(?wikidata_enlabel)="en")
               optional{?wikidata rdfs:label ?wikidata_lalabel. filter (lang(?wikidata_lalabel)="la")}
               ?wikidata schema:description ?wikidata_desc. filter (lang(?wikidata_desc)="en")
               optional{?wikidata wdt:P2888 ?lexinfo_match.  filter(regex(str(?lexinfo_match),"http://www.lexinfo.net/ontology/3.0/lexinfo#")) }
              }
    }
  
  
} group by ?feat ?feat_label ?leipzig ?udp_maps ?wikidata ?wikidata_enlabel ?wikidata_lalabel ?wikidata_desc ?lexinfo_match 
order by ?leipzig

Try it!


UDP morphological features for Latin

Paralex Cells

LiLaMorph Wikibase classes and properties

  • Query for LiLaMorph Wikibase ontology classes and number of instances: Query.
  • List of all properties here.
Retrieved from "https://lilamorph.wikibase.cloud/w/index.php?title=Main_Page&oldid=483080"